Izdelava začetne strani s ključnimi kazalniki

Na prvi strani aplikacije pokažite, kaj zahteva pozornost – številke s stanjem, merilnik za obremenitev –, in z enim klikom odprite ustrezni seznam.

Zahteva WKL Forms Object Library 1.44 ali novejšo različico.

• En WklKpiCard za vsako številko, ki lahko zahteva ukrepanje. StatusText in StatusKind povesta, ali ga zahteva; Compare in DeltaKind prikažeta spremembo od zadnje osvežitve.
• WklGauge za obremenitev glede na meje, z obsegi za stanja v redu, opozorilo in slabo.
• Časovnik osvežuje vrednosti (Form_Timer); nič ni vezano, zato stran deluje s katerim koli virom podatkov, tudi s povezanim naborom OData.
• Click(Key) odpre seznam. Vsaka kartica ima Key; ena procedura odpre seznam s filtrom za ta ključ.

Obrazec frmStart s karticama kpiLocked in kpiExpiring ter merilnikom gauLoad (vstavite jih z gradniki kontrolnikov ali v pogovornem oknu za vstavljanje kontrolnikov ActiveX), TimerInterval 5000:

Private Sub Form_Load()
    With Me!kpiLocked.Object
        .Title = "Zaklenjene osebe"
        .Key = "locked"
        .Clickable = True
        .StatusKind = wskBad
    End With
    With Me!kpiExpiring.Object
        .Title = "Potečejo v 30 dneh"
        .Key = "expiring"
        .Clickable = True
        .StatusKind = wskWarn
    End With
    With Me!gauLoad.Object
        .Caption = "Prijave na minuto"
        .Max = 200
        .AddRange 0, 120, wskOk
        .AddRange 120, 170, wskWarn
        .AddRange 170, 200, wskBad
    End With
    Form_Timer
End Sub
 
Private Sub Form_Timer()
    ShowCount Me!kpiLocked.Object, DCount("*", "tblOsebe", "Stanje = 'zaklenjeno'"), "Potrebno ukrepanje"
    ShowCount Me!kpiExpiring.Object, DCount("*", "tblOsebe", "Potek Between Date() And Date() + 30"), "Opozorilo"
    Me!gauLoad.Object.Value = DLookup("NaMinuto", "qryPrijaveNaMinuto")
End Sub
 
Private Sub ShowCount(ByVal card As Object, ByVal count As Long, ByVal needsAction As String)
    card.Compare = card.Value
    card.Value = count
    card.StatusText = IIf(count > 0, needsAction, "")
    card.AddPoint count
End Sub
 
Private Sub kpiLocked_Click(ByVal Key As String)
    OpenList Key
End Sub
 
Private Sub kpiExpiring_Click(ByVal Key As String)
    OpenList Key
End Sub
 
Private Sub OpenList(ByVal key As String)
    Select Case key
        Case "locked": DoCmd.OpenForm "frmOsebe", , , "Stanje = 'zaklenjeno'"
        Case "expiring": DoCmd.OpenForm "frmOsebe", , , "Potek Between Date() And Date() + 30"
    End Select
End Sub

• Prva osvežitev nima primerjalne vrednosti (Compare je do druge osvežitve Null), zato odstopanje še ni prikazano.
• Črtni mini grafikon potrebuje prostor pod vrednostjo: na nizki kartici je izpuščen.
• V lupini z WklNavBar seznam odprite kot stran podobrazca namesto v oknu: nastavite SourceObject podobrazca strani in SelectedKey vrstice, filter pa strani predajte v spremenljivki modula, ki jo prebere njen Form_Load; tako dela predloga WKL Administration Shell Template.

• WklGauge in WklKpiCard
• Referenčni priročnik API (v angleščini): WklKpiCard
• Referenčni priročnik API (v angleščini): WklGauge